Monorepo for Tangled
tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 fenix = {
7 url = "github:nix-community/fenix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 gomod2nix = {
11 url = "github:nix-community/gomod2nix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 flake-compat = {
15 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
16 flake = false;
17 };
18 indigo = {
19 url = "github:oppiliappan/indigo";
20 flake = false;
21 };
22 htmx-src = {
23 url = "https://cdn.jsdelivr.net/npm/htmx.org@2.0.10/dist/htmx.min.js";
24 flake = false;
25 };
26 htmx-ws-src = {
27 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.4";
28 flake = false;
29 };
30 lucide-src = {
31 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
32 flake = false;
33 };
34 inter-fonts-src = {
35 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
36 flake = false;
37 };
38 actor-typeahead-src = {
39 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
40 flake = false;
41 };
42 mermaid-src = {
43 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
44 flake = false;
45 };
46 ibm-plex-mono-src = {
47 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
48 flake = false;
49 };
50 sqlite-lib-src = {
51 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
52 flake = false;
53 };
54 };
55
56 outputs = {
57 self,
58 nixpkgs,
59 fenix,
60 gomod2nix,
61 indigo,
62 htmx-src,
63 htmx-ws-src,
64 lucide-src,
65 inter-fonts-src,
66 sqlite-lib-src,
67 ibm-plex-mono-src,
68 actor-typeahead-src,
69 mermaid-src,
70 ...
71 }: let
72 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
73 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
74 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
75
76 mkPackageSet = pkgs:
77 pkgs.lib.makeScope pkgs.newScope (self: {
78 src = let
79 fs = pkgs.lib.fileset;
80 in
81 fs.toSource {
82 root = ./.;
83 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
84 };
85 buildGoApplication =
86 (self.callPackage "${gomod2nix}/builder" {
87 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
88 }).buildGoApplication;
89 rustPlatform = pkgs.makeRustPlatform {
90 inherit (fenix.packages.${pkgs.system}.stable) rustc cargo;
91 };
92 modules = ./nix/gomod2nix.toml;
93 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
94 inherit sqlite-lib-src;
95 };
96 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
97 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
98 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
99 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src;
100 };
101 appview = self.callPackage ./nix/pkgs/appview.nix {};
102 blog = self.callPackage ./nix/pkgs/blog.nix {};
103 docs = self.callPackage ./nix/pkgs/docs.nix {
104 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
105 inherit (pkgs) pagefind;
106 };
107 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
108 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
109 knot = self.callPackage ./nix/pkgs/knot.nix {};
110 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
111 tap = self.callPackage ./nix/pkgs/tap.nix {};
112 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
113 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
114 });
115 in {
116 overlays.default = final: prev: {
117 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly tap knotmirror bobbin;
118 };
119
120 packages = forAllSystems (system: let
121 pkgs = nixpkgsFor.${system};
122 packages = mkPackageSet pkgs;
123 staticPackages = mkPackageSet pkgs.pkgsStatic;
124 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
125 in {
126 inherit
127 (packages)
128 appview
129 appview-static-files
130 blog
131 lexgen
132 goat
133 spindle
134 knot
135 knot-unwrapped
136 sqlite-lib
137 docs
138 dolly
139 tap
140 knotmirror
141 bobbin
142 ;
143
144 pkgsStatic-appview = staticPackages.appview;
145 pkgsStatic-knot = staticPackages.knot;
146 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
147 pkgsStatic-spindle = staticPackages.spindle;
148 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
149 pkgsStatic-dolly = staticPackages.dolly;
150
151 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
152 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
153 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
154 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
155 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
156
157 treefmt-wrapper = pkgs.treefmt.withConfig {
158 settings.formatter = {
159 alejandra = {
160 command = pkgs.lib.getExe pkgs.alejandra;
161 includes = ["*.nix"];
162 };
163
164 gofmt = {
165 command = pkgs.lib.getExe' pkgs.go "gofmt";
166 options = ["-w"];
167 includes = ["*.go"];
168 };
169
170 rustfmt = {
171 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
172 options = ["--edition" "2024"];
173 includes = ["*.rs"];
174 excludes = ["**/src/_lex/**"];
175 };
176
177 # prettier = let
178 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
179 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
180 # '';
181 # in {
182 # command = wrapper;
183 # options = ["-w"];
184 # includes = ["*.html"];
185 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
186 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
187 # };
188 };
189 };
190 });
191 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
192 devShells = forAllSystems (system: let
193 pkgs = nixpkgsFor.${system};
194 packages' = self.packages.${system};
195 staticShell = args:
196 (pkgs.mkShell.override {
197 stdenv = pkgs.pkgsStatic.stdenv;
198 }) (args
199 // {
200 nativeBuildInputs =
201 args.nativeBuildInputs
202 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
203 pkgs.darwin.cctools
204 ];
205 });
206 in {
207 default = staticShell {
208 nativeBuildInputs = [
209 pkgs.go
210 pkgs.air
211 pkgs.gopls
212 pkgs.httpie
213 pkgs.litecli
214 pkgs.websocat
215 pkgs.tailwindcss
216 pkgs.nixos-shell
217 pkgs.redis
218 pkgs.worker-build
219 pkgs.cargo-generate
220 (fenix.packages.${system}.combine [
221 fenix.packages.${system}.stable.cargo
222 fenix.packages.${system}.stable.rustc
223 fenix.packages.${system}.stable.rust-src
224 fenix.packages.${system}.stable.clippy
225 fenix.packages.${system}.stable.rustfmt
226 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
227 ])
228 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
229 packages'.lexgen
230 packages'.treefmt-wrapper
231 packages'.tap
232 ];
233 shellHook = ''
234 mkdir -p appview/pages/static
235 # temporary self-heal for workspaces that copied static assets as read-only
236 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
237 # no preserve is needed because watch-tailwind will want to be able to overwrite
238 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
239 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
240 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
241 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
242 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
243 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
244 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
245 fi
246 '';
247 env.CGO_ENABLED = 1;
248 };
249 });
250 apps = forAllSystems (system: let
251 pkgs = nixpkgsFor."${system}";
252 packages' = self.packages.${system};
253 air-watcher = name: arg:
254 pkgs.writeShellScriptBin "run"
255 ''
256 export PATH=${pkgs.go}/bin:$PATH
257 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
258 -build.args_bin "${arg}"
259 '';
260 tailwind-watcher =
261 pkgs.writeShellScriptBin "run"
262 ''
263 export BROWSERSLIST_IGNORE_OLD_DATA=true
264 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
265 '';
266 in {
267 watch-appview = {
268 type = "app";
269 program = toString (pkgs.writeShellScript "watch-appview" ''
270 echo "copying static files to appview/pages/static..."
271 mkdir -p appview/pages/static
272 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
273 ${air-watcher "appview" ""}/bin/run
274 '');
275 };
276 watch-knot = {
277 type = "app";
278 program = ''${air-watcher "knot" "server"}/bin/run'';
279 };
280 watch-spindle = {
281 type = "app";
282 program = ''${air-watcher "spindle" ""}/bin/run'';
283 };
284 watch-blog = {
285 type = "app";
286 program = toString (pkgs.writeShellScript "watch-blog" ''
287 echo "copying static files to appview/pages/static..."
288 mkdir -p appview/pages/static
289 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
290 ${air-watcher "blog" "serve"}/bin/run
291 '');
292 };
293 watch-tailwind = {
294 type = "app";
295 program = ''${tailwind-watcher}/bin/run'';
296 };
297 serve-docs = {
298 type = "app";
299 program = toString (pkgs.writeShellScript "serve-docs" ''
300 echo "building docs..."
301 docsOut=$(nix build --no-link --print-out-paths .#docs)
302 echo "serving docs at http://localhost:1414"
303 cd "$docsOut"
304 exec ${pkgs.python3}/bin/python3 -m http.server 1414
305 '');
306 };
307 vm = let
308 guestSystem =
309 if pkgs.stdenv.hostPlatform.isAarch64
310 then "aarch64-linux"
311 else "x86_64-linux";
312 in {
313 type = "app";
314 program =
315 (pkgs.writeShellApplication {
316 name = "launch-vm";
317 text = ''
318 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
319 cd "$rootDir"
320
321 # Reset TMPDIR in case it points to a stale nix-shell temp dir
322 export TMPDIR=/tmp
323
324 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
325
326 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
327 exec ${pkgs.lib.getExe
328 (import ./nix/vm.nix {
329 inherit nixpkgs self;
330 system = guestSystem;
331 hostSystem = system;
332 }).config.system.build.vm}
333 '';
334 })
335 + /bin/launch-vm;
336 };
337 gomod2nix = {
338 type = "app";
339 program = toString (pkgs.writeShellScript "gomod2nix" ''
340 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
341 '');
342 };
343 lexgen = {
344 type = "app";
345 program =
346 (pkgs.writeShellApplication {
347 name = "lexgen";
348 text = ''
349 if ! command -v lexgen > /dev/null; then
350 echo "error: must be executed from devshell"
351 exit 1
352 fi
353
354 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
355 cd "$rootDir"
356
357 rm -f api/tangled/*
358 lexgen --build-file lexicon-build-config.json lexicons
359 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
360 # lexgen generates incomplete Marshaler/Unmarshaler for union types
361 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
362 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
363 ${pkgs.gotools}/bin/goimports -w api/tangled/*
364 go run ./cmd/cborgen/
365 lexgen --build-file lexicon-build-config.json lexicons
366 rm api/tangled/*.bak
367 '';
368 })
369 + /bin/lexgen;
370 };
371 });
372
373 nixosModules.appview = {
374 lib,
375 pkgs,
376 ...
377 }: {
378 imports = [./nix/modules/appview.nix];
379
380 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
381 };
382 nixosModules.knotmirror = {
383 lib,
384 pkgs,
385 ...
386 }: {
387 imports = [./nix/modules/knotmirror.nix];
388
389 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
390 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
391 };
392 nixosModules.knot = {
393 lib,
394 pkgs,
395 ...
396 }: {
397 imports = [./nix/modules/knot.nix];
398
399 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
400 };
401 nixosModules.spindle = {
402 lib,
403 pkgs,
404 ...
405 }: {
406 imports = [./nix/modules/spindle.nix];
407
408 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
409 };
410
411 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
412 };
413}