Monorepo for Tangled
tangled.org
1{
2 nixpkgs,
3 system,
4 hostSystem,
5 self,
6}: let
7 envVar = name: let
8 var = builtins.getEnv name;
9 in
10 if var == ""
11 then throw "\$${name} must be defined, see https://docs.tangled.org/hacking-on-tangled.html#hacking-on-tangled for more details"
12 else var;
13 envVarOr = name: default: let
14 var = builtins.getEnv name;
15 in
16 if var != ""
17 then var
18 else default;
19
20 plcUrl = envVarOr "TANGLED_VM_PLC_URL" "https://plc.directory";
21 jetstream = envVarOr "TANGLED_VM_JETSTREAM_ENDPOINT" "wss://jetstream1.us-west.bsky.network/subscribe";
22in
23 nixpkgs.lib.nixosSystem {
24 inherit system;
25 modules = [
26 self.nixosModules.knot
27 self.nixosModules.spindle
28 self.nixosModules.knotmirror
29 ({
30 lib,
31 config,
32 pkgs,
33 ...
34 }: {
35 virtualisation.vmVariant.virtualisation = {
36 host.pkgs = import nixpkgs {system = hostSystem;};
37
38 graphics = false;
39 memorySize = 2048;
40 diskSize = 10 * 1024;
41 cores = 2;
42 forwardPorts = [
43 # ssh
44 {
45 from = "host";
46 host.port = 2222;
47 guest.port = 22;
48 }
49 # knot
50 {
51 from = "host";
52 host.port = 6444;
53 guest.port = 6444;
54 }
55 # spindle
56 {
57 from = "host";
58 host.port = 6555;
59 guest.port = 6555;
60 }
61 # knotmirror
62 {
63 from = "host";
64 host.port = 7007; # 7000 is deserved in macos for Airplay
65 guest.port = 7000;
66 }
67 # knotmirror-tap
68 {
69 from = "host";
70 host.port = 7480;
71 guest.port = 7480;
72 }
73 # knotmirror-admin
74 {
75 from = "host";
76 host.port = 7200;
77 guest.port = 7200;
78 }
79 {
80 from = "host";
81 host.port = 7100;
82 guest.port = 7100;
83 }
84 ];
85 sharedDirectories = {
86 # We can't use the 9p mounts directly for most of these
87 # as SQLite is incompatible with them. So instead we
88 # mount the shared directories to a different location
89 # and copy the contents around on service start/stop.
90 knotData = {
91 source = "$TANGLED_VM_DATA_DIR/knot";
92 target = "/mnt/knot-data";
93 };
94 spindleData = {
95 source = "$TANGLED_VM_DATA_DIR/spindle";
96 target = "/mnt/spindle-data";
97 };
98 spindleLogs = {
99 source = "$TANGLED_VM_DATA_DIR/spindle-logs";
100 target = "/var/log/spindle";
101 };
102 };
103 };
104 # This is fine because any and all ports that are forwarded to host are explicitly marked above, we don't need a separate guest firewall
105 networking.firewall.enable = false;
106 services.timesyncd.enable = lib.mkForce true;
107 time.timeZone = "Europe/London";
108 services.getty.autologinUser = "root";
109 environment.systemPackages = with pkgs; [curl vim git sqlite litecli postgresql_14];
110 services.tangled.knot = {
111 enable = true;
112 motd = "Welcome to the development knot!\n";
113 server = {
114 secureMode = false;
115 owner = envVar "TANGLED_VM_KNOT_OWNER";
116 hostname = envVarOr "TANGLED_VM_KNOT_HOST" "localhost:6444";
117 plcUrl = plcUrl;
118 jetstreamEndpoint = jetstream;
119 listenAddr = "0.0.0.0:6444";
120 dev = true;
121 };
122 knotmirrors = [
123 "http://localhost:7000"
124 ];
125 };
126 services.tangled.spindle = {
127 enable = true;
128 server = {
129 owner = envVar "TANGLED_VM_SPINDLE_OWNER";
130 hostname = envVarOr "TANGLED_VM_SPINDLE_HOST" "localhost:6555";
131 plcUrl = plcUrl;
132 jetstreamEndpoint = jetstream;
133 listenAddr = "0.0.0.0:6555";
134 dev = true;
135 queueSize = 100;
136 maxJobCount = 2;
137 secrets = {
138 provider = "sqlite";
139 };
140 };
141
142 pipelines = {
143 logBucket = envVarOr "SPINDLE_S3_LOG_BUCKET" "";
144 };
145 };
146 services.postgresql = {
147 enable = true;
148 package = pkgs.postgresql_14;
149 ensureDatabases = ["mirror" "tap"];
150 ensureUsers = [
151 {name = "tnglr";}
152 ];
153 authentication = ''
154 local all tnglr trust
155 host all tnglr 127.0.0.1/32 trust
156 '';
157 };
158 services.tangled.knotmirror = {
159 enable = true;
160 knotSSRF = false;
161 listenAddr = "0.0.0.0:7000";
162 metricsListenAddr = "0.0.0.0:7100";
163 adminListenAddr = "0.0.0.0:7200";
164 hostname = "localhost:7000";
165 dbUrl = "postgresql://tnglr@127.0.0.1:5432/mirror";
166 fullNetwork = false;
167 tap.dbUrl = "postgresql://tnglr@127.0.0.1:5432/tap";
168 };
169 users = {
170 # So we don't have to deal with permission clashing between
171 # blank disk VMs and existing state
172 users.${config.services.tangled.knot.gitUser}.uid = 666;
173 groups.${config.services.tangled.knot.gitUser}.gid = 666;
174
175 # TODO: separate spindle user
176 };
177 systemd.services = let
178 mkDataSyncScripts = source: target: {
179 enableStrictShellChecks = true;
180
181 preStart = lib.mkBefore ''
182 mkdir -p ${target}
183 ${lib.getExe pkgs.rsync} -a ${source}/ ${target}
184 '';
185
186 postStop = lib.mkAfter ''
187 ${lib.getExe pkgs.rsync} -a ${target}/ ${source}
188 '';
189
190 serviceConfig.PermissionsStartOnly = true;
191 };
192 in {
193 knot = mkDataSyncScripts "/mnt/knot-data" config.services.tangled.knot.stateDir;
194 spindle = mkDataSyncScripts "/mnt/spindle-data" (builtins.dirOf config.services.tangled.spindle.server.dbPath);
195 knotmirror.after = ["postgresql.target"];
196 tap-knotmirror.after = ["postgresql.target"];
197 };
198 })
199 ];
200 }