Monorepo for Tangled
tangled.org
1{
2 nixpkgs,
3 system,
4 hostSystem,
5 self,
6}: let
7 envVar = name: let
8 var = builtins.getEnv name;
9 in
10 if var == ""
11 then throw "\$${name} must be defined, see https://docs.tangled.org/hacking-on-tangled.html#hacking-on-tangled for more details"
12 else var;
13 envVarOr = name: default: let
14 var = builtins.getEnv name;
15 in
16 if var != ""
17 then var
18 else default;
19
20 plcUrl = envVarOr "TANGLED_VM_PLC_URL" "https://plc.directory";
21 jetstream = envVarOr "TANGLED_VM_JETSTREAM_ENDPOINT" "wss://jetstream1.us-west.bsky.network/subscribe";
22in
23 nixpkgs.lib.nixosSystem {
24 inherit system;
25 modules = [
26 self.nixosModules.knot
27 self.nixosModules.spindle
28 self.nixosModules.knotmirror
29 ({
30 lib,
31 config,
32 pkgs,
33 ...
34 }: {
35 virtualisation.vmVariant.virtualisation = {
36 host.pkgs = import nixpkgs {system = hostSystem;};
37
38 graphics = false;
39 memorySize = 2048;
40 diskSize = 10 * 1024;
41 cores = 2;
42 forwardPorts = [
43 # ssh
44 {
45 from = "host";
46 host.port = 2222;
47 guest.port = 22;
48 }
49 # knot
50 {
51 from = "host";
52 host.port = 6444;
53 guest.port = 6444;
54 }
55 # spindle
56 {
57 from = "host";
58 host.port = 6555;
59 guest.port = 6555;
60 }
61 # knotmirror
62 {
63 from = "host";
64 host.port = 7007; # 7000 is deserved in macos for Airplay
65 guest.port = 7000;
66 }
67 # knotmirror-tap
68 {
69 from = "host";
70 host.port = 7480;
71 guest.port = 7480;
72 }
73 # knotmirror-admin
74 {
75 from = "host";
76 host.port = 7200;
77 guest.port = 7200;
78 }
79 {
80 from = "host";
81 host.port = 7100;
82 guest.port = 7100;
83 }
84 ];
85 sharedDirectories = {
86 # We can't use the 9p mounts directly for most of these
87 # as SQLite is incompatible with them. So instead we
88 # mount the shared directories to a different location
89 # and copy the contents around on service start/stop.
90 knotData = {
91 source = "$TANGLED_VM_DATA_DIR/knot";
92 target = "/mnt/knot-data";
93 };
94 spindleData = {
95 source = "$TANGLED_VM_DATA_DIR/spindle";
96 target = "/mnt/spindle-data";
97 };
98 spindleLogs = {
99 source = "$TANGLED_VM_DATA_DIR/spindle-logs";
100 target = "/var/log/spindle";
101 };
102 };
103 };
104 # This is fine because any and all ports that are forwarded to host are explicitly marked above, we don't need a separate guest firewall
105 networking.firewall.enable = false;
106 time.timeZone = "Europe/London";
107 services.getty.autologinUser = "root";
108 environment.systemPackages = with pkgs; [curl vim git sqlite litecli postgresql_14];
109 services.tangled.knot = {
110 enable = true;
111 motd = "Welcome to the development knot!\n";
112 server = {
113 owner = envVar "TANGLED_VM_KNOT_OWNER";
114 hostname = envVarOr "TANGLED_VM_KNOT_HOST" "localhost:6444";
115 plcUrl = plcUrl;
116 jetstreamEndpoint = jetstream;
117 listenAddr = "0.0.0.0:6444";
118 dev = true;
119 };
120 knotmirrors = [
121 "http://localhost:7000"
122 ];
123 };
124 services.tangled.spindle = {
125 enable = true;
126 server = {
127 owner = envVar "TANGLED_VM_SPINDLE_OWNER";
128 hostname = envVarOr "TANGLED_VM_SPINDLE_HOST" "localhost:6555";
129 plcUrl = plcUrl;
130 jetstreamEndpoint = jetstream;
131 listenAddr = "0.0.0.0:6555";
132 dev = true;
133 queueSize = 100;
134 maxJobCount = 2;
135 secrets = {
136 provider = "sqlite";
137 };
138 };
139
140 pipelines = {
141 logBucket = envVarOr "SPINDLE_S3_LOG_BUCKET" "";
142 };
143 };
144 services.postgresql = {
145 enable = true;
146 package = pkgs.postgresql_14;
147 ensureDatabases = ["mirror" "tap"];
148 ensureUsers = [
149 {name = "tnglr";}
150 ];
151 authentication = ''
152 local all tnglr trust
153 host all tnglr 127.0.0.1/32 trust
154 '';
155 };
156 services.tangled.knotmirror = {
157 enable = true;
158 listenAddr = "0.0.0.0:7000";
159 metricsListenAddr = "0.0.0.0:7100";
160 adminListenAddr = "0.0.0.0:7200";
161 hostname = "localhost:7000";
162 dbUrl = "postgresql://tnglr@127.0.0.1:5432/mirror";
163 fullNetwork = false;
164 tap.dbUrl = "postgresql://tnglr@127.0.0.1:5432/tap";
165 };
166 users = {
167 # So we don't have to deal with permission clashing between
168 # blank disk VMs and existing state
169 users.${config.services.tangled.knot.gitUser}.uid = 666;
170 groups.${config.services.tangled.knot.gitUser}.gid = 666;
171
172 # TODO: separate spindle user
173 };
174 systemd.services = let
175 mkDataSyncScripts = source: target: {
176 enableStrictShellChecks = true;
177
178 preStart = lib.mkBefore ''
179 mkdir -p ${target}
180 ${lib.getExe pkgs.rsync} -a ${source}/ ${target}
181 '';
182
183 postStop = lib.mkAfter ''
184 ${lib.getExe pkgs.rsync} -a ${target}/ ${source}
185 '';
186
187 serviceConfig.PermissionsStartOnly = true;
188 };
189 in {
190 knot = mkDataSyncScripts "/mnt/knot-data" config.services.tangled.knot.stateDir;
191 spindle = mkDataSyncScripts "/mnt/spindle-data" (builtins.dirOf config.services.tangled.spindle.server.dbPath);
192 knotmirror.after = ["postgresql.target"];
193 tap-knotmirror.after = ["postgresql.target"];
194 };
195 })
196 ];
197 }