Monorepo for Tangled
tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 fenix = {
7 url = "github:nix-community/fenix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 gomod2nix = {
11 url = "github:nix-community/gomod2nix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 flake-compat = {
15 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
16 flake = false;
17 };
18 indigo = {
19 url = "github:oppiliappan/indigo";
20 flake = false;
21 };
22 htmx-src = {
23 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
24 flake = false;
25 };
26 htmx-ws-src = {
27 # strange errors in console that i can't really make out
28 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
29 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
30 flake = false;
31 };
32 lucide-src = {
33 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
34 flake = false;
35 };
36 inter-fonts-src = {
37 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
38 flake = false;
39 };
40 actor-typeahead-src = {
41 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
42 flake = false;
43 };
44 mermaid-src = {
45 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
46 flake = false;
47 };
48 ibm-plex-mono-src = {
49 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
50 flake = false;
51 };
52 sqlite-lib-src = {
53 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
54 flake = false;
55 };
56 };
57
58 outputs = {
59 self,
60 nixpkgs,
61 fenix,
62 gomod2nix,
63 indigo,
64 htmx-src,
65 htmx-ws-src,
66 lucide-src,
67 inter-fonts-src,
68 sqlite-lib-src,
69 ibm-plex-mono-src,
70 actor-typeahead-src,
71 mermaid-src,
72 ...
73 }: let
74 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
75 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
76 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
77
78 mkPackageSet = pkgs:
79 pkgs.lib.makeScope pkgs.newScope (self: {
80 src = let
81 fs = pkgs.lib.fileset;
82 in
83 fs.toSource {
84 root = ./.;
85 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
86 };
87 buildGoApplication =
88 (self.callPackage "${gomod2nix}/builder" {
89 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
90 }).buildGoApplication;
91 modules = ./nix/gomod2nix.toml;
92 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
93 inherit sqlite-lib-src;
94 };
95 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
96 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
97 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
98 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src;
99 };
100 appview = self.callPackage ./nix/pkgs/appview.nix {};
101 blog = self.callPackage ./nix/pkgs/blog.nix {};
102 docs = self.callPackage ./nix/pkgs/docs.nix {
103 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
104 inherit (pkgs) pagefind;
105 };
106 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
107 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
108 knot = self.callPackage ./nix/pkgs/knot.nix {};
109 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
110 tap = self.callPackage ./nix/pkgs/tap.nix {};
111 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
112 });
113 in {
114 overlays.default = final: prev: {
115 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly tap knotmirror;
116 };
117
118 packages = forAllSystems (system: let
119 pkgs = nixpkgsFor.${system};
120 packages = mkPackageSet pkgs;
121 staticPackages = mkPackageSet pkgs.pkgsStatic;
122 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
123 in {
124 inherit
125 (packages)
126 appview
127 appview-static-files
128 blog
129 lexgen
130 goat
131 spindle
132 knot
133 knot-unwrapped
134 sqlite-lib
135 docs
136 dolly
137 tap
138 knotmirror
139 ;
140
141 pkgsStatic-appview = staticPackages.appview;
142 pkgsStatic-knot = staticPackages.knot;
143 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
144 pkgsStatic-spindle = staticPackages.spindle;
145 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
146 pkgsStatic-dolly = staticPackages.dolly;
147
148 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
149 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
150 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
151 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
152 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
153
154 treefmt-wrapper = pkgs.treefmt.withConfig {
155 settings.formatter = {
156 alejandra = {
157 command = pkgs.lib.getExe pkgs.alejandra;
158 includes = ["*.nix"];
159 };
160
161 gofmt = {
162 command = pkgs.lib.getExe' pkgs.go "gofmt";
163 options = ["-w"];
164 includes = ["*.go"];
165 };
166
167 # prettier = let
168 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
169 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
170 # '';
171 # in {
172 # command = wrapper;
173 # options = ["-w"];
174 # includes = ["*.html"];
175 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
176 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
177 # };
178 };
179 };
180 });
181 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
182 devShells = forAllSystems (system: let
183 pkgs = nixpkgsFor.${system};
184 packages' = self.packages.${system};
185 staticShell = args:
186 (pkgs.mkShell.override {
187 stdenv = pkgs.pkgsStatic.stdenv;
188 }) (args
189 // {
190 nativeBuildInputs =
191 args.nativeBuildInputs
192 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
193 pkgs.darwin.cctools
194 ];
195 });
196 in {
197 default = staticShell {
198 nativeBuildInputs = [
199 pkgs.go
200 pkgs.air
201 pkgs.gopls
202 pkgs.httpie
203 pkgs.litecli
204 pkgs.websocat
205 pkgs.tailwindcss
206 pkgs.nixos-shell
207 pkgs.redis
208 pkgs.worker-build
209 pkgs.cargo-generate
210 (fenix.packages.${system}.combine [
211 fenix.packages.${system}.stable.cargo
212 fenix.packages.${system}.stable.rustc
213 fenix.packages.${system}.stable.rust-src
214 fenix.packages.${system}.stable.clippy
215 fenix.packages.${system}.stable.rustfmt
216 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
217 ])
218 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
219 packages'.lexgen
220 packages'.treefmt-wrapper
221 packages'.tap
222 ];
223 shellHook = ''
224 mkdir -p appview/pages/static
225 # temporary self-heal for workspaces that copied static assets as read-only
226 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
227 # no preserve is needed because watch-tailwind will want to be able to overwrite
228 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
229 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
230 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
231 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
232 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
233 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
234 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
235 fi
236 '';
237 env.CGO_ENABLED = 1;
238 };
239 });
240 apps = forAllSystems (system: let
241 pkgs = nixpkgsFor."${system}";
242 packages' = self.packages.${system};
243 air-watcher = name: arg:
244 pkgs.writeShellScriptBin "run"
245 ''
246 export PATH=${pkgs.go}/bin:$PATH
247 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
248 -build.args_bin "${arg}"
249 '';
250 tailwind-watcher =
251 pkgs.writeShellScriptBin "run"
252 ''
253 export BROWSERSLIST_IGNORE_OLD_DATA=true
254 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
255 '';
256 in {
257 fmt = {
258 type = "app";
259 program = pkgs.lib.getExe packages'.treefmt-wrapper;
260 };
261 watch-appview = {
262 type = "app";
263 program = toString (pkgs.writeShellScript "watch-appview" ''
264 echo "copying static files to appview/pages/static..."
265 mkdir -p appview/pages/static
266 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
267 ${air-watcher "appview" ""}/bin/run
268 '');
269 };
270 watch-knot = {
271 type = "app";
272 program = ''${air-watcher "knot" "server"}/bin/run'';
273 };
274 watch-spindle = {
275 type = "app";
276 program = ''${air-watcher "spindle" ""}/bin/run'';
277 };
278 watch-blog = {
279 type = "app";
280 program = toString (pkgs.writeShellScript "watch-blog" ''
281 echo "copying static files to appview/pages/static..."
282 mkdir -p appview/pages/static
283 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
284 ${air-watcher "blog" "serve"}/bin/run
285 '');
286 };
287 watch-tailwind = {
288 type = "app";
289 program = ''${tailwind-watcher}/bin/run'';
290 };
291 serve-docs = {
292 type = "app";
293 program = toString (pkgs.writeShellScript "serve-docs" ''
294 echo "building docs..."
295 docsOut=$(nix build --no-link --print-out-paths .#docs)
296 echo "serving docs at http://localhost:1414"
297 cd "$docsOut"
298 exec ${pkgs.python3}/bin/python3 -m http.server 1414
299 '');
300 };
301 vm = let
302 guestSystem =
303 if pkgs.stdenv.hostPlatform.isAarch64
304 then "aarch64-linux"
305 else "x86_64-linux";
306 in {
307 type = "app";
308 program =
309 (pkgs.writeShellApplication {
310 name = "launch-vm";
311 text = ''
312 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
313 cd "$rootDir"
314
315 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
316
317 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
318 exec ${pkgs.lib.getExe
319 (import ./nix/vm.nix {
320 inherit nixpkgs self;
321 system = guestSystem;
322 hostSystem = system;
323 }).config.system.build.vm}
324 '';
325 })
326 + /bin/launch-vm;
327 };
328 gomod2nix = {
329 type = "app";
330 program = toString (pkgs.writeShellScript "gomod2nix" ''
331 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
332 '');
333 };
334 lexgen = {
335 type = "app";
336 program =
337 (pkgs.writeShellApplication {
338 name = "lexgen";
339 text = ''
340 if ! command -v lexgen > /dev/null; then
341 echo "error: must be executed from devshell"
342 exit 1
343 fi
344
345 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
346 cd "$rootDir"
347
348 rm -f api/tangled/*
349 lexgen --build-file lexicon-build-config.json lexicons
350 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
351 # lexgen generates incomplete Marshaler/Unmarshaler for union types
352 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
353 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
354 ${pkgs.gotools}/bin/goimports -w api/tangled/*
355 go run ./cmd/cborgen/
356 lexgen --build-file lexicon-build-config.json lexicons
357 rm api/tangled/*.bak
358 '';
359 })
360 + /bin/lexgen;
361 };
362 });
363
364 nixosModules.appview = {
365 lib,
366 pkgs,
367 ...
368 }: {
369 imports = [./nix/modules/appview.nix];
370
371 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
372 };
373 nixosModules.knotmirror = {
374 lib,
375 pkgs,
376 ...
377 }: {
378 imports = [./nix/modules/knotmirror.nix];
379
380 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
381 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
382 };
383 nixosModules.knot = {
384 lib,
385 pkgs,
386 ...
387 }: {
388 imports = [./nix/modules/knot.nix];
389
390 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
391 };
392 nixosModules.spindle = {
393 lib,
394 pkgs,
395 ...
396 }: {
397 imports = [./nix/modules/spindle.nix];
398
399 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
400 };
401 };
402}