Monorepo for Tangled
tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 fenix = {
7 url = "github:nix-community/fenix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 gomod2nix = {
11 url = "github:nix-community/gomod2nix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 flake-compat = {
15 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
16 flake = false;
17 };
18 indigo = {
19 url = "github:oppiliappan/indigo";
20 flake = false;
21 };
22 htmx-src = {
23 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
24 flake = false;
25 };
26 htmx-ws-src = {
27 # strange errors in console that i can't really make out
28 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
29 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
30 flake = false;
31 };
32 lucide-src = {
33 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
34 flake = false;
35 };
36 inter-fonts-src = {
37 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
38 flake = false;
39 };
40 actor-typeahead-src = {
41 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
42 flake = false;
43 };
44 mermaid-src = {
45 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
46 flake = false;
47 };
48 ibm-plex-mono-src = {
49 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
50 flake = false;
51 };
52 sqlite-lib-src = {
53 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
54 flake = false;
55 };
56 };
57
58 outputs = {
59 self,
60 nixpkgs,
61 fenix,
62 gomod2nix,
63 indigo,
64 htmx-src,
65 htmx-ws-src,
66 lucide-src,
67 inter-fonts-src,
68 sqlite-lib-src,
69 ibm-plex-mono-src,
70 actor-typeahead-src,
71 mermaid-src,
72 ...
73 }: let
74 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
75 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
76 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
77
78 mkPackageSet = pkgs:
79 pkgs.lib.makeScope pkgs.newScope (self: {
80 src = let
81 fs = pkgs.lib.fileset;
82 in
83 fs.toSource {
84 root = ./.;
85 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
86 };
87 buildGoApplication =
88 (self.callPackage "${gomod2nix}/builder" {
89 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
90 }).buildGoApplication;
91 modules = ./nix/gomod2nix.toml;
92 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
93 inherit sqlite-lib-src;
94 };
95 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
96 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
97 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
98 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src;
99 };
100 appview = self.callPackage ./nix/pkgs/appview.nix {};
101 blog = self.callPackage ./nix/pkgs/blog.nix {};
102 docs = self.callPackage ./nix/pkgs/docs.nix {
103 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
104 inherit (pkgs) pagefind;
105 };
106 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
107 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
108 knot = self.callPackage ./nix/pkgs/knot.nix {};
109 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
110 tap = self.callPackage ./nix/pkgs/tap.nix {};
111 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
112 });
113 in {
114 overlays.default = final: prev: {
115 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly tap knotmirror;
116 };
117
118 packages = forAllSystems (system: let
119 pkgs = nixpkgsFor.${system};
120 packages = mkPackageSet pkgs;
121 staticPackages = mkPackageSet pkgs.pkgsStatic;
122 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
123 in {
124 inherit
125 (packages)
126 appview
127 appview-static-files
128 blog
129 lexgen
130 goat
131 spindle
132 knot
133 knot-unwrapped
134 sqlite-lib
135 docs
136 dolly
137 tap
138 knotmirror
139 ;
140
141 pkgsStatic-appview = staticPackages.appview;
142 pkgsStatic-knot = staticPackages.knot;
143 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
144 pkgsStatic-spindle = staticPackages.spindle;
145 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
146 pkgsStatic-dolly = staticPackages.dolly;
147
148 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
149 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
150 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
151 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
152 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
153
154 treefmt-wrapper = pkgs.treefmt.withConfig {
155 settings.formatter = {
156 alejandra = {
157 command = pkgs.lib.getExe pkgs.alejandra;
158 includes = ["*.nix"];
159 };
160
161 gofmt = {
162 command = pkgs.lib.getExe' pkgs.go "gofmt";
163 options = ["-w"];
164 includes = ["*.go"];
165 };
166
167 rustfmt = {
168 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
169 options = ["--edition" "2024"];
170 includes = ["*.rs"];
171 };
172
173 # prettier = let
174 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
175 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
176 # '';
177 # in {
178 # command = wrapper;
179 # options = ["-w"];
180 # includes = ["*.html"];
181 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
182 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
183 # };
184 };
185 };
186 });
187 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
188 devShells = forAllSystems (system: let
189 pkgs = nixpkgsFor.${system};
190 packages' = self.packages.${system};
191 staticShell = args:
192 (pkgs.mkShell.override {
193 stdenv = pkgs.pkgsStatic.stdenv;
194 }) (args
195 // {
196 nativeBuildInputs =
197 args.nativeBuildInputs
198 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
199 pkgs.darwin.cctools
200 ];
201 });
202 in {
203 default = staticShell {
204 nativeBuildInputs = [
205 pkgs.go
206 pkgs.air
207 pkgs.gopls
208 pkgs.httpie
209 pkgs.litecli
210 pkgs.websocat
211 pkgs.tailwindcss
212 pkgs.nixos-shell
213 pkgs.redis
214 pkgs.worker-build
215 pkgs.cargo-generate
216 (fenix.packages.${system}.combine [
217 fenix.packages.${system}.stable.cargo
218 fenix.packages.${system}.stable.rustc
219 fenix.packages.${system}.stable.rust-src
220 fenix.packages.${system}.stable.clippy
221 fenix.packages.${system}.stable.rustfmt
222 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
223 ])
224 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
225 packages'.lexgen
226 packages'.treefmt-wrapper
227 packages'.tap
228 ];
229 shellHook = ''
230 mkdir -p appview/pages/static
231 # temporary self-heal for workspaces that copied static assets as read-only
232 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
233 # no preserve is needed because watch-tailwind will want to be able to overwrite
234 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
235 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
236 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
237 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
238 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
239 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
240 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
241 fi
242 '';
243 env.CGO_ENABLED = 1;
244 };
245 });
246 apps = forAllSystems (system: let
247 pkgs = nixpkgsFor."${system}";
248 packages' = self.packages.${system};
249 air-watcher = name: arg:
250 pkgs.writeShellScriptBin "run"
251 ''
252 export PATH=${pkgs.go}/bin:$PATH
253 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
254 -build.args_bin "${arg}"
255 '';
256 tailwind-watcher =
257 pkgs.writeShellScriptBin "run"
258 ''
259 export BROWSERSLIST_IGNORE_OLD_DATA=true
260 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
261 '';
262 in {
263 fmt = {
264 type = "app";
265 program = pkgs.lib.getExe packages'.treefmt-wrapper;
266 };
267 watch-appview = {
268 type = "app";
269 program = toString (pkgs.writeShellScript "watch-appview" ''
270 echo "copying static files to appview/pages/static..."
271 mkdir -p appview/pages/static
272 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
273 ${air-watcher "appview" ""}/bin/run
274 '');
275 };
276 watch-knot = {
277 type = "app";
278 program = ''${air-watcher "knot" "server"}/bin/run'';
279 };
280 watch-spindle = {
281 type = "app";
282 program = ''${air-watcher "spindle" ""}/bin/run'';
283 };
284 watch-blog = {
285 type = "app";
286 program = toString (pkgs.writeShellScript "watch-blog" ''
287 echo "copying static files to appview/pages/static..."
288 mkdir -p appview/pages/static
289 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
290 ${air-watcher "blog" "serve"}/bin/run
291 '');
292 };
293 watch-tailwind = {
294 type = "app";
295 program = ''${tailwind-watcher}/bin/run'';
296 };
297 serve-docs = {
298 type = "app";
299 program = toString (pkgs.writeShellScript "serve-docs" ''
300 echo "building docs..."
301 docsOut=$(nix build --no-link --print-out-paths .#docs)
302 echo "serving docs at http://localhost:1414"
303 cd "$docsOut"
304 exec ${pkgs.python3}/bin/python3 -m http.server 1414
305 '');
306 };
307 vm = let
308 guestSystem =
309 if pkgs.stdenv.hostPlatform.isAarch64
310 then "aarch64-linux"
311 else "x86_64-linux";
312 in {
313 type = "app";
314 program =
315 (pkgs.writeShellApplication {
316 name = "launch-vm";
317 text = ''
318 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
319 cd "$rootDir"
320
321 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
322
323 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
324 exec ${pkgs.lib.getExe
325 (import ./nix/vm.nix {
326 inherit nixpkgs self;
327 system = guestSystem;
328 hostSystem = system;
329 }).config.system.build.vm}
330 '';
331 })
332 + /bin/launch-vm;
333 };
334 gomod2nix = {
335 type = "app";
336 program = toString (pkgs.writeShellScript "gomod2nix" ''
337 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
338 '');
339 };
340 lexgen = {
341 type = "app";
342 program =
343 (pkgs.writeShellApplication {
344 name = "lexgen";
345 text = ''
346 if ! command -v lexgen > /dev/null; then
347 echo "error: must be executed from devshell"
348 exit 1
349 fi
350
351 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
352 cd "$rootDir"
353
354 rm -f api/tangled/*
355 lexgen --build-file lexicon-build-config.json lexicons
356 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
357 # lexgen generates incomplete Marshaler/Unmarshaler for union types
358 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
359 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
360 ${pkgs.gotools}/bin/goimports -w api/tangled/*
361 go run ./cmd/cborgen/
362 lexgen --build-file lexicon-build-config.json lexicons
363 rm api/tangled/*.bak
364 '';
365 })
366 + /bin/lexgen;
367 };
368 });
369
370 nixosModules.appview = {
371 lib,
372 pkgs,
373 ...
374 }: {
375 imports = [./nix/modules/appview.nix];
376
377 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
378 };
379 nixosModules.knotmirror = {
380 lib,
381 pkgs,
382 ...
383 }: {
384 imports = [./nix/modules/knotmirror.nix];
385
386 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
387 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
388 };
389 nixosModules.knot = {
390 lib,
391 pkgs,
392 ...
393 }: {
394 imports = [./nix/modules/knot.nix];
395
396 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
397 };
398 nixosModules.spindle = {
399 lib,
400 pkgs,
401 ...
402 }: {
403 imports = [./nix/modules/spindle.nix];
404
405 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
406 };
407 };
408}