Monorepo for Tangled
tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 fenix = {
7 url = "github:nix-community/fenix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 gomod2nix = {
11 url = "github:nix-community/gomod2nix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 flake-compat = {
15 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
16 flake = false;
17 };
18 indigo = {
19 url = "github:oppiliappan/indigo";
20 flake = false;
21 };
22 htmx-src = {
23 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
24 flake = false;
25 };
26 htmx-ws-src = {
27 # strange errors in console that i can't really make out
28 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
29 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
30 flake = false;
31 };
32 lucide-src = {
33 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
34 flake = false;
35 };
36 inter-fonts-src = {
37 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
38 flake = false;
39 };
40 actor-typeahead-src = {
41 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
42 flake = false;
43 };
44 mermaid-src = {
45 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
46 flake = false;
47 };
48 ibm-plex-mono-src = {
49 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
50 flake = false;
51 };
52 sqlite-lib-src = {
53 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
54 flake = false;
55 };
56 };
57
58 outputs = {
59 self,
60 nixpkgs,
61 fenix,
62 gomod2nix,
63 indigo,
64 htmx-src,
65 htmx-ws-src,
66 lucide-src,
67 inter-fonts-src,
68 sqlite-lib-src,
69 ibm-plex-mono-src,
70 actor-typeahead-src,
71 mermaid-src,
72 ...
73 }: let
74 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
75 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
76 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
77
78 mkPackageSet = pkgs:
79 pkgs.lib.makeScope pkgs.newScope (self: {
80 src = let
81 fs = pkgs.lib.fileset;
82 in
83 fs.toSource {
84 root = ./.;
85 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
86 };
87 buildGoApplication =
88 (self.callPackage "${gomod2nix}/builder" {
89 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
90 }).buildGoApplication;
91 modules = ./nix/gomod2nix.toml;
92 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
93 inherit sqlite-lib-src;
94 };
95 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
96 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
97 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
98 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src;
99 };
100 appview = self.callPackage ./nix/pkgs/appview.nix {};
101 blog = self.callPackage ./nix/pkgs/blog.nix {};
102 docs = self.callPackage ./nix/pkgs/docs.nix {
103 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
104 inherit (pkgs) pagefind;
105 };
106 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
107 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
108 knot = self.callPackage ./nix/pkgs/knot.nix {};
109 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
110 tap = self.callPackage ./nix/pkgs/tap.nix {};
111 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
112 });
113 in {
114 overlays.default = final: prev: {
115 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly tap knotmirror;
116 };
117
118 packages = forAllSystems (system: let
119 pkgs = nixpkgsFor.${system};
120 packages = mkPackageSet pkgs;
121 staticPackages = mkPackageSet pkgs.pkgsStatic;
122 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
123 in {
124 inherit
125 (packages)
126 appview
127 appview-static-files
128 blog
129 lexgen
130 goat
131 spindle
132 knot
133 knot-unwrapped
134 sqlite-lib
135 docs
136 dolly
137 tap
138 knotmirror
139 ;
140
141 pkgsStatic-appview = staticPackages.appview;
142 pkgsStatic-knot = staticPackages.knot;
143 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
144 pkgsStatic-spindle = staticPackages.spindle;
145 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
146 pkgsStatic-dolly = staticPackages.dolly;
147
148 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
149 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
150 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
151 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
152 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
153
154 treefmt-wrapper = pkgs.treefmt.withConfig {
155 settings.formatter = {
156 alejandra = {
157 command = pkgs.lib.getExe pkgs.alejandra;
158 includes = ["*.nix"];
159 };
160
161 gofmt = {
162 command = pkgs.lib.getExe' pkgs.go "gofmt";
163 options = ["-w"];
164 includes = ["*.go"];
165 };
166
167 rustfmt = {
168 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
169 options = ["--edition" "2024"];
170 includes = ["*.rs"];
171 excludes = ["**/src/_lex/**"];
172 };
173
174 # prettier = let
175 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
176 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
177 # '';
178 # in {
179 # command = wrapper;
180 # options = ["-w"];
181 # includes = ["*.html"];
182 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
183 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
184 # };
185 };
186 };
187 });
188 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
189 devShells = forAllSystems (system: let
190 pkgs = nixpkgsFor.${system};
191 packages' = self.packages.${system};
192 staticShell = args:
193 (pkgs.mkShell.override {
194 stdenv = pkgs.pkgsStatic.stdenv;
195 }) (args
196 // {
197 nativeBuildInputs =
198 args.nativeBuildInputs
199 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
200 pkgs.darwin.cctools
201 ];
202 });
203 in {
204 default = staticShell {
205 nativeBuildInputs = [
206 pkgs.go
207 pkgs.air
208 pkgs.gopls
209 pkgs.httpie
210 pkgs.litecli
211 pkgs.websocat
212 pkgs.tailwindcss
213 pkgs.nixos-shell
214 pkgs.redis
215 pkgs.worker-build
216 pkgs.cargo-generate
217 (fenix.packages.${system}.combine [
218 fenix.packages.${system}.stable.cargo
219 fenix.packages.${system}.stable.rustc
220 fenix.packages.${system}.stable.rust-src
221 fenix.packages.${system}.stable.clippy
222 fenix.packages.${system}.stable.rustfmt
223 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
224 ])
225 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
226 packages'.lexgen
227 packages'.treefmt-wrapper
228 packages'.tap
229 ];
230 shellHook = ''
231 mkdir -p appview/pages/static
232 # temporary self-heal for workspaces that copied static assets as read-only
233 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
234 # no preserve is needed because watch-tailwind will want to be able to overwrite
235 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
236 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
237 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
238 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
239 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
240 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
241 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
242 fi
243 '';
244 env.CGO_ENABLED = 1;
245 };
246 });
247 apps = forAllSystems (system: let
248 pkgs = nixpkgsFor."${system}";
249 packages' = self.packages.${system};
250 air-watcher = name: arg:
251 pkgs.writeShellScriptBin "run"
252 ''
253 export PATH=${pkgs.go}/bin:$PATH
254 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
255 -build.args_bin "${arg}"
256 '';
257 tailwind-watcher =
258 pkgs.writeShellScriptBin "run"
259 ''
260 export BROWSERSLIST_IGNORE_OLD_DATA=true
261 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
262 '';
263 in {
264 fmt = {
265 type = "app";
266 program = pkgs.lib.getExe packages'.treefmt-wrapper;
267 };
268 watch-appview = {
269 type = "app";
270 program = toString (pkgs.writeShellScript "watch-appview" ''
271 echo "copying static files to appview/pages/static..."
272 mkdir -p appview/pages/static
273 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
274 ${air-watcher "appview" ""}/bin/run
275 '');
276 };
277 watch-knot = {
278 type = "app";
279 program = ''${air-watcher "knot" "server"}/bin/run'';
280 };
281 watch-spindle = {
282 type = "app";
283 program = ''${air-watcher "spindle" ""}/bin/run'';
284 };
285 watch-blog = {
286 type = "app";
287 program = toString (pkgs.writeShellScript "watch-blog" ''
288 echo "copying static files to appview/pages/static..."
289 mkdir -p appview/pages/static
290 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
291 ${air-watcher "blog" "serve"}/bin/run
292 '');
293 };
294 watch-tailwind = {
295 type = "app";
296 program = ''${tailwind-watcher}/bin/run'';
297 };
298 serve-docs = {
299 type = "app";
300 program = toString (pkgs.writeShellScript "serve-docs" ''
301 echo "building docs..."
302 docsOut=$(nix build --no-link --print-out-paths .#docs)
303 echo "serving docs at http://localhost:1414"
304 cd "$docsOut"
305 exec ${pkgs.python3}/bin/python3 -m http.server 1414
306 '');
307 };
308 vm = let
309 guestSystem =
310 if pkgs.stdenv.hostPlatform.isAarch64
311 then "aarch64-linux"
312 else "x86_64-linux";
313 in {
314 type = "app";
315 program =
316 (pkgs.writeShellApplication {
317 name = "launch-vm";
318 text = ''
319 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
320 cd "$rootDir"
321
322 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
323
324 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
325 exec ${pkgs.lib.getExe
326 (import ./nix/vm.nix {
327 inherit nixpkgs self;
328 system = guestSystem;
329 hostSystem = system;
330 }).config.system.build.vm}
331 '';
332 })
333 + /bin/launch-vm;
334 };
335 gomod2nix = {
336 type = "app";
337 program = toString (pkgs.writeShellScript "gomod2nix" ''
338 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
339 '');
340 };
341 lexgen = {
342 type = "app";
343 program =
344 (pkgs.writeShellApplication {
345 name = "lexgen";
346 text = ''
347 if ! command -v lexgen > /dev/null; then
348 echo "error: must be executed from devshell"
349 exit 1
350 fi
351
352 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
353 cd "$rootDir"
354
355 rm -f api/tangled/*
356 lexgen --build-file lexicon-build-config.json lexicons
357 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
358 # lexgen generates incomplete Marshaler/Unmarshaler for union types
359 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
360 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
361 ${pkgs.gotools}/bin/goimports -w api/tangled/*
362 go run ./cmd/cborgen/
363 lexgen --build-file lexicon-build-config.json lexicons
364 rm api/tangled/*.bak
365 '';
366 })
367 + /bin/lexgen;
368 };
369 });
370
371 nixosModules.appview = {
372 lib,
373 pkgs,
374 ...
375 }: {
376 imports = [./nix/modules/appview.nix];
377
378 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
379 };
380 nixosModules.knotmirror = {
381 lib,
382 pkgs,
383 ...
384 }: {
385 imports = [./nix/modules/knotmirror.nix];
386
387 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
388 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
389 };
390 nixosModules.knot = {
391 lib,
392 pkgs,
393 ...
394 }: {
395 imports = [./nix/modules/knot.nix];
396
397 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
398 };
399 nixosModules.spindle = {
400 lib,
401 pkgs,
402 ...
403 }: {
404 imports = [./nix/modules/spindle.nix];
405
406 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
407 };
408 };
409}