Monorepo for Tangled
tangled.org
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6 fenix = {
7 url = "github:nix-community/fenix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 gomod2nix = {
11 url = "github:nix-community/gomod2nix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 flake-compat = {
15 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
16 flake = false;
17 };
18 indigo = {
19 url = "github:oppiliappan/indigo";
20 flake = false;
21 };
22 htmx-src = {
23 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
24 flake = false;
25 };
26 htmx-ws-src = {
27 # strange errors in console that i can't really make out
28 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
29 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
30 flake = false;
31 };
32 lucide-src = {
33 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
34 flake = false;
35 };
36 inter-fonts-src = {
37 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
38 flake = false;
39 };
40 actor-typeahead-src = {
41 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
42 flake = false;
43 };
44 mermaid-src = {
45 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
46 flake = false;
47 };
48 ibm-plex-mono-src = {
49 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
50 flake = false;
51 };
52 sqlite-lib-src = {
53 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
54 flake = false;
55 };
56 };
57
58 outputs = {
59 self,
60 nixpkgs,
61 fenix,
62 gomod2nix,
63 indigo,
64 htmx-src,
65 htmx-ws-src,
66 lucide-src,
67 inter-fonts-src,
68 sqlite-lib-src,
69 ibm-plex-mono-src,
70 actor-typeahead-src,
71 mermaid-src,
72 ...
73 }: let
74 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
75 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
76 nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
77
78 mkPackageSet = pkgs:
79 pkgs.lib.makeScope pkgs.newScope (self: {
80 src = let
81 fs = pkgs.lib.fileset;
82 in
83 fs.toSource {
84 root = ./.;
85 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
86 };
87 buildGoApplication =
88 (self.callPackage "${gomod2nix}/builder" {
89 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
90 }).buildGoApplication;
91 modules = ./nix/gomod2nix.toml;
92 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
93 inherit sqlite-lib-src;
94 };
95 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
96 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
97 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
98 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src;
99 };
100 appview = self.callPackage ./nix/pkgs/appview.nix {};
101 blog = self.callPackage ./nix/pkgs/blog.nix {};
102 docs = self.callPackage ./nix/pkgs/docs.nix {
103 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
104 inherit (pkgs) pagefind;
105 };
106 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
107 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
108 knot = self.callPackage ./nix/pkgs/knot.nix {};
109 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
110 tap = self.callPackage ./nix/pkgs/tap.nix {};
111 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
112 });
113 in {
114 overlays.default = final: prev: {
115 inherit (mkPackageSet final) lexgen goat sqlite-lib spindle knot-unwrapped knot appview docs dolly tap knotmirror;
116 };
117
118 packages = forAllSystems (system: let
119 pkgs = nixpkgsFor.${system};
120 packages = mkPackageSet pkgs;
121 staticPackages = mkPackageSet pkgs.pkgsStatic;
122 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
123 in {
124 inherit
125 (packages)
126 appview
127 appview-static-files
128 blog
129 lexgen
130 goat
131 spindle
132 knot
133 knot-unwrapped
134 sqlite-lib
135 docs
136 dolly
137 tap
138 knotmirror
139 ;
140
141 pkgsStatic-appview = staticPackages.appview;
142 pkgsStatic-knot = staticPackages.knot;
143 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
144 pkgsStatic-spindle = staticPackages.spindle;
145 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
146 pkgsStatic-dolly = staticPackages.dolly;
147
148 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
149 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
150 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
151 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
152 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
153
154 treefmt-wrapper = pkgs.treefmt.withConfig {
155 settings.formatter = {
156 alejandra = {
157 command = pkgs.lib.getExe pkgs.alejandra;
158 includes = ["*.nix"];
159 };
160
161 gofmt = {
162 command = pkgs.lib.getExe' pkgs.go "gofmt";
163 options = ["-w"];
164 includes = ["*.go"];
165 };
166
167 # prettier = let
168 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
169 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
170 # '';
171 # in {
172 # command = wrapper;
173 # options = ["-w"];
174 # includes = ["*.html"];
175 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
176 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
177 # };
178 };
179 };
180 });
181 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
182 devShells = forAllSystems (system: let
183 pkgs = nixpkgsFor.${system};
184 packages' = self.packages.${system};
185 staticShell = args: (pkgs.mkShell.override {
186 stdenv = pkgs.pkgsStatic.stdenv;
187 }) (args // {
188 nativeBuildInputs = args.nativeBuildInputs
189 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
190 pkgs.darwin.cctools
191 ];
192 });
193 in {
194 default = staticShell {
195 nativeBuildInputs = [
196 pkgs.go
197 pkgs.air
198 pkgs.gopls
199 pkgs.httpie
200 pkgs.litecli
201 pkgs.websocat
202 pkgs.tailwindcss
203 pkgs.nixos-shell
204 pkgs.redis
205 pkgs.worker-build
206 pkgs.cargo-generate
207 (fenix.packages.${system}.combine [
208 fenix.packages.${system}.stable.cargo
209 fenix.packages.${system}.stable.rustc
210 fenix.packages.${system}.stable.rust-src
211 fenix.packages.${system}.stable.clippy
212 fenix.packages.${system}.stable.rustfmt
213 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
214 ])
215 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
216 packages'.lexgen
217 packages'.treefmt-wrapper
218 packages'.tap
219 ];
220 shellHook = ''
221 mkdir -p appview/pages/static
222 # temporary self-heal for workspaces that copied static assets as read-only
223 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
224 # no preserve is needed because watch-tailwind will want to be able to overwrite
225 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
226 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
227 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
228 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
229 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
230 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
231 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
232 fi
233 '';
234 env.CGO_ENABLED = 1;
235 };
236 });
237 apps = forAllSystems (system: let
238 pkgs = nixpkgsFor."${system}";
239 packages' = self.packages.${system};
240 air-watcher = name: arg:
241 pkgs.writeShellScriptBin "run"
242 ''
243 export PATH=${pkgs.go}/bin:$PATH
244 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
245 -build.args_bin "${arg}"
246 '';
247 tailwind-watcher =
248 pkgs.writeShellScriptBin "run"
249 ''
250 export BROWSERSLIST_IGNORE_OLD_DATA=true
251 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
252 '';
253 in {
254 fmt = {
255 type = "app";
256 program = pkgs.lib.getExe packages'.treefmt-wrapper;
257 };
258 watch-appview = {
259 type = "app";
260 program = toString (pkgs.writeShellScript "watch-appview" ''
261 echo "copying static files to appview/pages/static..."
262 mkdir -p appview/pages/static
263 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
264 ${air-watcher "appview" ""}/bin/run
265 '');
266 };
267 watch-knot = {
268 type = "app";
269 program = ''${air-watcher "knot" "server"}/bin/run'';
270 };
271 watch-spindle = {
272 type = "app";
273 program = ''${air-watcher "spindle" ""}/bin/run'';
274 };
275 watch-blog = {
276 type = "app";
277 program = toString (pkgs.writeShellScript "watch-blog" ''
278 echo "copying static files to appview/pages/static..."
279 mkdir -p appview/pages/static
280 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
281 ${air-watcher "blog" "serve"}/bin/run
282 '');
283 };
284 watch-tailwind = {
285 type = "app";
286 program = ''${tailwind-watcher}/bin/run'';
287 };
288 serve-docs = {
289 type = "app";
290 program = toString (pkgs.writeShellScript "serve-docs" ''
291 echo "building docs..."
292 docsOut=$(nix build --no-link --print-out-paths .#docs)
293 echo "serving docs at http://localhost:1414"
294 cd "$docsOut"
295 exec ${pkgs.python3}/bin/python3 -m http.server 1414
296 '');
297 };
298 vm = let
299 guestSystem =
300 if pkgs.stdenv.hostPlatform.isAarch64
301 then "aarch64-linux"
302 else "x86_64-linux";
303 in {
304 type = "app";
305 program =
306 (pkgs.writeShellApplication {
307 name = "launch-vm";
308 text = ''
309 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
310 cd "$rootDir"
311
312 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
313
314 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
315 exec ${pkgs.lib.getExe
316 (import ./nix/vm.nix {
317 inherit nixpkgs self;
318 system = guestSystem;
319 hostSystem = system;
320 }).config.system.build.vm}
321 '';
322 })
323 + /bin/launch-vm;
324 };
325 gomod2nix = {
326 type = "app";
327 program = toString (pkgs.writeShellScript "gomod2nix" ''
328 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
329 '');
330 };
331 lexgen = {
332 type = "app";
333 program =
334 (pkgs.writeShellApplication {
335 name = "lexgen";
336 text = ''
337 if ! command -v lexgen > /dev/null; then
338 echo "error: must be executed from devshell"
339 exit 1
340 fi
341
342 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
343 cd "$rootDir"
344
345 rm -f api/tangled/*
346 lexgen --build-file lexicon-build-config.json lexicons
347 sed -i.bak 's/\tutil/\/\/\tutil/' api/tangled/*
348 # lexgen generates incomplete Marshaler/Unmarshaler for union types
349 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
350 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
351 ${pkgs.gotools}/bin/goimports -w api/tangled/*
352 go run ./cmd/cborgen/
353 lexgen --build-file lexicon-build-config.json lexicons
354 rm api/tangled/*.bak
355 '';
356 })
357 + /bin/lexgen;
358 };
359 });
360
361 nixosModules.appview = {
362 lib,
363 pkgs,
364 ...
365 }: {
366 imports = [./nix/modules/appview.nix];
367
368 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
369 };
370 nixosModules.knotmirror = {
371 lib,
372 pkgs,
373 ...
374 }: {
375 imports = [./nix/modules/knotmirror.nix];
376
377 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
378 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
379 };
380 nixosModules.knot = {
381 lib,
382 pkgs,
383 ...
384 }: {
385 imports = [./nix/modules/knot.nix];
386
387 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
388 };
389 nixosModules.spindle = {
390 lib,
391 pkgs,
392 ...
393 }: {
394 imports = [./nix/modules/spindle.nix];
395
396 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
397 };
398 };
399}