struct Frame {
    viewport_px: vec2<f32>,
    _pad: vec2<f32>,
};

@group(0) @binding(0) var<uniform> u: Frame;
@group(0) @binding(1) var atlas: texture_2d<f32>;
@group(0) @binding(2) var atlas_sampler: sampler;

struct VsOut {
    @builtin(position) clip: vec4<f32>,
    @location(0) uv: vec2<f32>,
    @location(1) color: vec4<f32>,
};

@vertex
fn vs(
    @builtin(vertex_index) vid: u32,
    @location(0) rect_xywh_px: vec4<f32>,
    @location(1) uv_min: vec2<f32>,
    @location(2) uv_max: vec2<f32>,
    @location(3) color: vec4<f32>,
) -> VsOut {
    var corners = array<vec2<f32>, 6>(
        vec2<f32>(0.0, 0.0),
        vec2<f32>(1.0, 0.0),
        vec2<f32>(0.0, 1.0),
        vec2<f32>(1.0, 0.0),
        vec2<f32>(1.0, 1.0),
        vec2<f32>(0.0, 1.0),
    );
    let c = corners[vid];
    let pos_px = rect_xywh_px.xy + c * rect_xywh_px.zw;
    let uv = mix(uv_min, uv_max, c);
    let ndc = vec2<f32>(
        (pos_px.x / u.viewport_px.x) * 2.0 - 1.0,
        1.0 - (pos_px.y / u.viewport_px.y) * 2.0,
    );
    var out: VsOut;
    out.clip = vec4<f32>(ndc, 0.0, 1.0);
    out.uv = uv;
    out.color = color;
    return out;
}

@fragment
fn fs(in: VsOut) -> @location(0) vec4<f32> {
    let s = textureSample(atlas, atlas_sampler, in.uv).r;
    let aa = max(fwidth(s), 1.0e-4);
    let alpha = 1.0 - smoothstep(0.5 - aa, 0.5 + aa, s);
    if alpha <= 0.0 {
        discard;
    }
    return in.color * alpha;
}
